► Recevez le fichier Excel de la vidéo + des exercices complets (avec sujet et corrigé sur Excel) de la formation Excel GRATUITEMENT : cours.excel-en...
► Lien vers les formations Excel : aidebtscgo.kne...
► Lien vers la vidéo "Recherche avec un critère en ligne et un critère en colonne" : urlz.fr/dpBh
▬▬▬ 📝 RÉSUMÉ DE LA VIDÉO ▬▬▬▬▬▬▬
Dans cette vidéo je vais vous montrer comment atterrir directement sur une cellule précise dans un tableau à double entrée et comment mettre en surbrillance cette cellule.
Si je clique sur « Trouver la valeur dans le tableau » le curseur se déplace automatiquement sur la cellule recherchée.
-----------------------------------------------------------------------
Dans l’exemple on a un tableau avec une liste de véhicules en ligne et des informations les concernant en colonne et on souhaite pouvoir retrouver le type d’information en fonction de l’immatriculation en faisant ces choix dans 2 listes déroulantes :
- Une liste déroulante pour le choix de l’immatriculation
- Une liste déroulante pour le choix du type d’information
Ici on souhaite créer un lien pour atteindre en un clic une valeur dans un tableau : Pour cela on va combiner les formules ADRESSE et LIEN_HYPERTEXTE.
-----------------------------------------------------------------------
Formule ADRESSE :
Permet de créer l’adresse d’une cellule en fonction du numéro de ligne et du numéro de colonne indiqués, c’est-à-dire de créer une référence de cellule sous forme de texte.
Exemple : =ADRESSE(3;2) renvoie la référence $B$3
On va pouvoir retrouver les numéros de ligne et de colonne en utilisant la formule EQUIV :
- Le numéro de colonne en recherchant l’information parmi les en-têtes.
- Le numéro de ligne en recherchant l’immatriculation dans la liste.
Par contre ici il faut bien veiller à prendre la totalité de la colonne pour le numéro de ligne et la totalité de la ligne pour le numéro de colonne pour ne pas créer de décalage pour l’adresse car la formule ADRESSE ne tient pas compte de l’emplacement du tableau dans la feuille et renvoie une référence de cellule en partant de la première cellule tout en haut à gauche.
Donc :
Num ligne =EQUIV($B$1;$A:$A;0)
Num colonne =EQUIV($B$2;$5:$5;0)
On peut imbriquer les formules EQUIV directement dans la formule ADRESSE pour n’avoir qu’une seule formule.
=ADRESSE(EQUIV($B$1;$A:$A;0);EQUIV($B$2;$5:$5;0))
-----------------------------------------------------------------------
Maintenant on va pouvoir avec créer un lien vers la cellule concernée justement à partir de cette référence de cellule obtenue.
Formule LIEN_HYPERTEXTE :
Permet de crée un raccourci qui renvoie à un autre emplacement soit dans le classeur actif, soit qui est stocké sur un serveur réseau ou sur Internet.
Dans l’exemple on souhaite créer un raccourci vers une cellule de la feuille active donc on va indiquer une référence de cellule pour l’emplacement.
Exemple : =LIEN_HYPERTEXTE("# B3") il faut bien indiquer l’emplacement du lien entre guillemet et avec un # (dièse) devant la référence de cellule.
Là encore on peut imbriquer la formule ADRESSE directement dans la formule LIEN_HYPERTEXTE :
=LIEN_HYPERTEXTE("#"&ADRESSE(EQUIV($B$1;$A:$A;0);EQUIV($B$2;$5:$5;0)))
-----------------------------------------------------------------------
On peut désormais ajouter l’argument facultatif « nom_convivial » pour remplacer la référence de cellule par une chaine de texte.
On va par exemple saisir « trouver dans le tableau » pour cet argument.
=LIEN_HYPERTEXTE("#"&ADRESSE(EQUIV($B$1;$A:$A;0);EQUIV($B$2;$5:$5;0));"Trouver dans le tableau")
-----------------------------------------------------------------------
Mise en forme conditionnelle :
Pour mettre en couleur la cellule qui contient le résultat on va comparer l’adresse de la cellule testée avec l’adresse de la cellule retrouvée par la formule ADRESSE.
Pour afficher l’adresse d’une cellule il faut utiliser la formule CELLULE qui permet de renvoyer un type d’information concernant la cellule notamment son adresse.
Exemple : =CELLULE("adresse";E10) renvoie l‘adresse « E10 ».
Il ne reste plus qu’à comparer ces 2 informations :
=ADRESSE(EQUIV($B$1;$A:$A;0);EQUIV($B$2;$5:$5;0))=CELLULE("adresse";E10)
On peut maintenant définir la mise en forme conditionnelle en partant de cette même formule de test qu’on va copier/coller :
Par contre il faut bien remplacer la référence de la cellule de la formule CELLULE par la première cellule tout en haut à gauche de la sélection pour que la mise en forme s’applique correctement et qu’il n’y ait pas de décalage.
-----------------------------------------------------------------------
#Excel #FormuleExcel #FormationExcel
► Le site : excel-en-ligne...
► FaceBook : / axelrobinformations
EXCEL - ATTEINDRE LA VALEUR CHERCHÉE DANS UN TABLEAU AU CLIC (Formules LIEN_HYPERTEXTE + ADRESSE) : • EXCEL - ATTEINDRE LA V...
Негізгі бет EXCEL - ATTEINDRE LA VALEUR CHERCHÉE DANS UN TABLEAU AU CLIC (Formules LIEN_HYPERTEXTE + ADRESSE)
Пікірлер: 21